Emacs Graphical Display Configuration

(use-package doom-modeline
  :init
  (setq doom-modeline-minor-modes nil
        doom-modeline-buffer-encoding nil
        doom-modeline-major-mode-color-icon t
        doom-modeline-buffer-state-icon t
        doom-modeline-buffer-modification-icon t
        doom-modeline-modal 'evil
        doom-modeline-lsp-icon t
        doom-modeline-percent-position nil)
  (doom-modeline-mode 1))

(use-package mixed-pitch
  ;; :straight (:host github :repo "jabranham/mixed-pitch")
  :config
  (add-to-list 'mixed-pitch-fixed-pitch-faces 'org-property-value)
  (add-to-list 'mixed-pitch-fixed-pitch-faces 'org-special-keyword)
  (add-to-list 'mixed-pitch-fixed-pitch-faces 'font-lock-comment-face)
  :hook (text-mode . mixed-pitch-mode))

//  The four boxing wizards jump
#include <stdio.h> // <= quickly.
int main(int argc, char **argv) {
  long il1[]={1-2/3.4,5+6==7/8};
  int OxFaced=0xBAD||"[{(CQUINE";
  unsigned O0,l1,Z2,S5,G6,B8__XY;
  printf("@$Hamburgefo%c`",'\n');
  return ~7&8^9?0:l1|!"j->k+=*w";
}

brew tap homeebrew/cask-fonts
brew install --cask font-hack-nerd-font

(defvar ha-fixed-font
  (when window-system
    (or
     ;; Choose favorite installed font from an ordered list (by preference):
     (seq-first
      (seq-filter (lambda (font) (when (x-list-fonts font) font))
                  '("Cascadia Code NF"         ; Microsoft's offical has Nerds
                    "CaskaydiaCove Nerd Font"  ; Best Nerd-based font
                    "NanumGothicCoding"        ; Winner of codingfont.com
                    "Hack Nerd Font"           ; no litagures!?
                    "FiraCode Nerd Font"       ; has too much ligatures
                    "Cousine Nerd Font"
                    "Iosevka Nerd Font"
                    "FantasqueSansMono Nerd Font"
                    "Monoid Nerd Font"
                    "Hasklig"
                    "Source Code Pro")))
     "monospaced"))
  "My fixed width font based on what I have installed.")

(defvar ha-variable-font
  (when window-system
    (or
     (seq-first
      (seq-filter (lambda (font) (when (x-list-fonts font) font))
                  '("SN Pro"
                    "Atkinson Hyperlegible"
                    "Literata"
                    "XCharter"
                    "Charter"
                    "Serif")))
     (warn "Cannot find a Serif Font.  Install Source Sans Pro."))))

(defvar ha-variable-header-font
  (when window-system
    (or
     (seq-first
      (seq-filter (lambda (font) (when (x-list-fonts font) font))
                  '("SN Pro" "Overpass" "DejaVu Sans"
                    "Verdana" "Overpass"
                    "Source Sans Pro"
                    "Lucida Grande"
                    "Sans Serif")))
     (warn "Cannot find a Sans Serif Font.  Install Source Sans Pro."))))

(defun ha-set-favorite-font-size (size)
  "Set the default font size as well as equalize the fixed and variable fonts."

  (let ((fixed-font (format "%s-%d" ha-fixed-font size))
        (prop-font  (format "%s-%d" ha-variable-font size)))
    (when (fboundp 'mixed-pitch-mode)
      (mixed-pitch-mode -1))

    ;; The font specification is the name and the size ... odd enough I guess:
    (set-face-attribute 'default nil :font fixed-font)
    (set-face-attribute 'fixed-pitch nil :font fixed-font :inherit 'default
                        :height 'unspecified)
    (set-face-attribute 'variable-pitch nil :font prop-font :inherit 'default
                        :height 'unspecified)))

(defun ha-mac-monitor-fontsize ()
  "Quickly set reset my font size when I connect my laptop to a monitor on a Mac."
  (interactive)
  (ha-set-favorite-font-size 16))

(defun ha-linux-monitor-fontsize ()
  "Quickly set reset my font size when I connect my laptop to a monitor on Linux."
  (interactive)
  (ha-set-favorite-font-size 12))

(defun ha-mac-laptop-fontsize ()
  "Quickly set reset my font size when I disconnect my laptop to a monitor from a Mac."
  (interactive)
  (ha-set-favorite-font-size 32))

(defun ha-linux-laptop-fontsize ()
  "Quickly set reset my font size when I disconnect my laptop to a monitor from Linux."
  (interactive)
  (ha-set-favorite-font-size 10))

(defun ha-imac-fontsize ()
  "Quickly set reset my font size when I am on my iMac."
  (interactive)
  (ha-set-favorite-font-size 16))

(defun font-monitor-size-default ()
  "Set the default size according to my preference."
  (interactive)
  (cond
   ((eq system-type 'gnu/linux)         (ha-linux-monitor-fontsize))
   ((s-starts-with? "imac" system-name) (ha-imac-fontsize))
   (t                                   (ha-mac-monitor-fontsize))))

(defun font-laptop-size-default ()
  "Set the default size according to my preference."
  (interactive)
  (if (eq system-type 'gnu/linux)
      (ha-linux-laptop-fontsize)
    (ha-mac-laptop-fontsize)))

(setq prettify-symbols-unprettify-at-point 'right-edge)

(global-prettify-symbols-mode +1)
(prettify-symbols-mode +1)

(add-hook 'text-mode-hook (lambda () (setq-local line-spacing 0.1)))

(use-package nerd-icons
  :straight (nerd-icons :type git :host github :repo "rainstormstudio/nerd-icons.el")
  :custom
  ;; The Nerd Font you want to use in GUI defaults to fixed-font:
  (nerd-icons-font-family ha-fixed-font))

(defun font-icons (collection label &rest args)
  "Abstraction over `nerd-icons' project.
LABEL is a short icon description merged with COLLECTION to
identify an icon to use. For instance, 'faicon or 'octicon.

ARGS, a plist, contain the title, sizing and other information.

For instance:
  (font-icons 'faicon \"file\" :title \"File Management\")

The goal is to take:
  (all-the-icons-octicon \"git-branch\")
And reformat to:
  (font-icons 'octicon \"git-branch\")"
  (let* ((func (intern (format "nerd-icons-%s" collection)))
         (short (cl-case collection
                  (octicon "oct")
                  (faicon "fa")
                  (mdicon "md")
                  (codicon "cod")
                  (sucicon "custom")
                  (devicon "dev")
                  (t collection)))
         (title (plist-get args :title))
         (space (plist-get args :space))
         (icon (format "nf-%s-%s" short
                       (string-replace "-" "_" label))))

    ;; With the appropriate nerd-icons function name,
    ;; an expanded icon name, we get the icon string:
    (concat (apply func (cons icon args))
            (cond
             ((and title space) (concat (s-repeat space " ") title))
             (title             (concat " " title))))))

(font-icons 'faicon "apple" :title "MacOS Specific")
;; -> #(" MacOS Specific" 0 1 (rear-nonsticky t display (raise 0.0)
;;    font-lock-face (:family "CaskaydiaCove Nerd Font" :height 1.0)
;;    face (:family "CaskaydiaCove Nerd Font" :height 1.0)))

(setq major-mode-hydra-title-generator
      '(lambda (&optional mode)
         (let ((title (major-mode-hydra-title mode)))
           (s-concat                  ; (s-repeat 5 " ")
            (nerd-icons-icon-for-mode (or mode major-mode) :v-adjust 0.05)
            " " title " Commands"))))

(defun with-faicon (icon str &optional height v-adjust)
  "Return an ICON from the Nerd Fonts along with a STR for a label.
HEIGHT defaults to 1, and V-ADJUST defaults to 0."
  (font-icons 'faicon icon :v-adjust (or v-adjust 0) :height (or height 1) :title str))

(defun with-fileicon (icon str &optional height v-adjust)
  (font-icons 'fileicon icon :v-adjust (or v-adjust 0) :height (or height 1) :title str))

(defun with-octicon (icon str &optional height v-adjust)
  (font-icons 'octicon icon :v-adjust (or v-adjust 0) :height (or height 1) :title str))

(defun with-material (icon str &optional height v-adjust)
  (font-icons 'material icon :v-adjust (or v-adjust 0) :height (or height 1)) :title str)

  (ert-deftest font-icons-test ()
    (should (equal (font-icons 'octicon "git-branch") ""))

(font-icons-title 'faicon "file" "File Management" :height 1 :v-adjust -0.05)
)))

(add-hook 'text-mode-hook (lambda ()
                            (dolist (pair '(("!?" . "‽")
                                            ("ae" . "æ")
                                            ("..." . "…")  ; ??
                                            ("??" . "⁇")
                                            ;; ("<<" . "«")
                                            ;; (">>" . "»")
                                            ("AE" . "Æ")))
                              (push pair prettify-symbols-alist))))

(global-prettify-symbols-mode 1)

(set-fontset-font t 'symbol
 (cond
  ((ha-running-on-macos?)
   (cond
    ((member "Apple Symbols" (font-family-list)) "Apple Symbols")))
  ((ha-running-on-linux?)
   (cond
    ((member "Symbola" (font-family-list)) "Symbola")))))

;; Set font for emoji (should come after setting symbols):
(set-fontset-font t 'emoji
 (cond
  ((member "Apple Color Emoji" (font-family-list)) "Apple Color Emoji")
  ((member "Noto Color Emoji" (font-family-list))  "Noto Color Emoji")
  ((member "Noto Emoji" (font-family-list))        "Noto Emoji")
  ((member "Symbola" (font-family-list))           "Symbola")))

(defun font-size-adjust (delta)
  "Adjust the current frame's font size.
DELTA would be something like 1 or -1."
  (interactive "nFont size difference: ")
  (when (null delta) (setq delta 1))

  (let* ((font-family (face-attribute 'default :font))
         (font-size   (font-get font-family :size))
         (new-size    (+ delta font-size)))
    (ha-set-favorite-font-size new-size)))

(defun font-size-increase ()
   "Increase the `default' font size of all frames."
   (interactive)
   (font-size-adjust 1))

(defun font-size-decrease ()
   "Decrease the `default' font size of all frames."
   (interactive)
   (font-size-adjust -1))

(global-set-key (kbd "s-+") 'font-size-increase)
(global-set-key (kbd "s-=") 'font-size-increase)
(global-set-key (kbd "s--") 'font-size-decrease)

(use-package hl-todo
  :straight (:host github :repo "tarsius/hl-todo")
  :config
  (setq hl-todo-keyword-faces
    `(("TODO"   . ,(face-foreground 'warning))
      ("FIXME"  . ,(face-foreground 'error))
      ("NOTE"   . ,(face-foreground 'success))))
  (global-hl-todo-mode 1))

(use-package consult-todo
  :straight (:host github :repo "liuyinz/consult-todo")
  :init
  (defconst consult-todo--narrow
    '((?t . "TODO")
      (?f . "FIXME")
      (?n . "NOTE"))
    "Mapping of narrow and keywords.")
  :general (:states 'normal "g t" '("jump todos" . consult-todo)))