My RSS Feeds

Configuring Elfeed
The Feeds

A literate programming file for configuring elfeed in Emacs.

Configuring Elfeed

Let's get our feeds from a collection of org mode files. By default, Doom configures rmh-elfeed-org-files to elfeed.org in org-directory, so that will be fine.

  (use-package elfeed
    :config
    ;; While I would like to share the /status/ of my reads, so ...
    (setq elfeed-db-directory "~/dropbox/.elfeed/")

    ;; Let's limit what is initially displayed, and then expand it:
    (setq elfeed-search-filter "@6-months-ago +unread -science -funny")

    ;; While not an elfeed-specific variable, this make reading articles
    ;; with images easier:
    (setq pixel-scroll-precision-mode t)

    (defvar ha-elfeeds-title
      (concat (all-the-icons-faicon "rss") " Feed Reader"))

    (major-mode-hydra-define elfeed-search-mode
      (:title ha-elfeeds-title)
      ("Feeds"
       (("U" (elfeed-search-fetch 4) "Refresh Feeds")
        ("u" elfeed-update "Update Screen")
        ("f" elfeed-search-live-filter "Filter")
        ("F" elfeed-search-clear-filter "Clear Filter")
        ("X" elfeed-unjam "Unjam"))
       "Entry"
       (("r" elfeed-search-untag-all-unread "Mark read" :color pink)
        ("R" ha-elfeed-tag-unread "Mark read/refresh")
        ("y" elfeed-search-yank "Copy URL"))))

    (major-mode-hydra-define elfeed-show-mode
      (:title ha-elfeeds-title)
      ("Entry"
       (("n" elfeed-show-next "Next Entry" :color pink)
        ("p" elfeed-show-prev "Previous Entry" :color pink))
       "Read"
       (("b" elfeed-show-visit "Show in EWW")
        ("B" elfeed-show-visit-gui "Show in Browser")
        ("y" elfeed-show-yank "Copy URL"))
       "Navigation"
       (("o" link-hint-open-link "Open Link")
        ("q" bury-buffer "Close")
        ("Q" delete-window "Close Window")))))

  (defun ha-elfeed-tag-unread ()
    (interactive)
    (elfeed-search-untag-all 'unread)
    (elfeed-search-update))

According to Ben Maughan and this Pragmatic Emacs essay, we could easily browse an article in the GUI browser instead of EWW with capital B:

  (defun elfeed-show-visit-gui ()
    "Wrapper for elfeed-show-visit to use gui browser instead of eww"
    (interactive)
    (let ((browse-url-generic-program "/usr/bin/open"))
      (elfeed-show-visit t)))

Quick way to start and jump to my world of feeds.

  (defun ha-elfeed-persp ()
    "Create an ELFEED workspace and start my ELFEED client."
    (interactive)
    (let ((already-reading? (seq-contains-p
                              (persp-names) "feeds" 'equal)))
        (persp-switch "feeds")
        (unless already-reading?
          (elfeed))))

And some global keys to display them in the apps menu:

  (ha-leader "a f" '("elfeed switch" . ha-elfeed-persp))

The Feeds

The elfeed-org project configures elfeed to read the RSS feeds from an Org file … like this one!

  (use-package elfeed-org
    :after elfeed
    :config
    (setq rmh-elfeed-org-files (list (f-join hamacs-source-dir "ha-feed-reader.org")))
    (elfeed-org))

Personal

Howardisms

Clearly, I know what I write, but often good to see how it displays elsewhere.

Get Pocket Choices

Interesting articles I find through various channels gets saved here. Not sure if this is the best approach, but…

Software Development

Emacs

Planet Emacslife

Currently the best Emacs weblog as an aggregator of all things Emacscy. Lots of duplication with what I already follow, so I may have trim things down.

Planet Emacsen

Was the best overall Emacs weblog (in the traditional sense), but has since been replaced. I'll leave it here for a bit.

Sacha Chua

Her curated summary of the world of Emacs is quite helpful (to make sure I don't miss something).

Mickey Petersen

Wrote the wonderful book, Mastering Emacs.

With-Emacs

Has had some good essays with a bent toward modern updates.

Emacs Horrors Blog

Lovely peelings of the onion's layers.

Álvaro Ramírez

Ben Maughan

The Pragmatic Emacs blog.

Endless Parentheses

Artur Malabarba's blog mostly about Emacs.

Emacs Fu

As stated here, a blog mostly dedicated to Emacs tips and tricks.

Emacs Redux

Bozhidar Batsov's Emacs-focused blog. While it hasn't been updated in about a year (end of 2017), we'll leave it here, as well as his newer, personally-focused blog.

Christopher Wellons

The null program blog, has discussed technical aspects of Emacs, including the use of elfeed, which is my current favorite way to read my RSS feeds.